I agree that interfaces are good, but that solution seems overly complicated to me.

The base page does not need to be involved at all and the button.click event handlers should be in the code behind for the master page.

If I were going to use interfaces to solve the example here’s what I would do:

Interface Definition

Public Interface IAddable
    Sub Add()
End Interface
 
Public Interface IEditable
    Sub Edit()
End Interface
 
Public Interface IDeletable
    Sub Delete()
End Interface
 
Public Interface IExitable
    Sub [Exit]()
End Interface
 
Public Interface ICommandButtonContainer
    ReadOnly Property AddButton() As Button
    ReadOnly Property EditButton() As Button
    ReadOnly Property DeleteButton() As Button
    ReadOnly Property ExitButton() As Button
End Interface

Code Behind for Master Page

Partial Class MasterPage
    Inherits System.Web.UI.MasterPage
    Implements ICommandButtonContainer
 
    Public ReadOnly Property AddButton() As System.Web.UI.WebControls.Button Implements ICommandButtonContainer.AddButton
        Get
            ‘return a reference to the button
            Return btnAdd
        End Get
    End Property
 
    Public ReadOnly Property DeleteButton() As System.Web.UI.WebControls.Button Implements ICommandButtonContainer.DeleteButton
        Get
            Return btnDelete
        End Get
    End Property
 
    Public ReadOnly Property EditButton() As System.Web.UI.WebControls.Button Implements ICommandButtonContainer.EditButton
        Get
            Return btnEdit
        End Get
    End Property
 
    Public ReadOnly Property ExitButton() As System.Web.UI.WebControls.Button Implements ICommandButtonContainer.ExitButton
        Get
            Return btnExit
        End Get
    End Property
 
    Protected Sub btnAdd_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnAdd.Click
        ‘if the child page implements IAddable then call it’s Add() method
        If TypeOf Page Is IAddable Then
            CType(Page, IAddable).Add()
        End If
    End Sub
 
    Protected Sub btnEdit_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnEdit.Click
        If TypeOf Page Is IEditable Then
            CType(Page, IEditable).Edit()
        End If
    End Sub
 
    Protected Sub btnDelete_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnDelete.Click
        If TypeOf Page Is IDeletable Then
            CType(Page, IDeletable).Delete()
        End If
    End Sub
 
    Protected Sub btnExit_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnExit.Click
        If TypeOf Page Is IExitable Then
            CType(Page, IExitable).Exit()
        End If
    End Sub
End Class

Code behind for Page

Partial Class _Default
    Inherits Web.UI.Page
    Implements IAddable, IDeletable, IEditable, IExitable
 
    Public Sub Add() Implements IAddable.Add
        WhatWasClicked.Text = “Add”
    End Sub
 
    Public Sub Delete() Implements IDeletable.Delete
        WhatWasClicked.Text = “Delete”
    End Sub
 
    Public Sub Edit() Implements IEditable.Edit
        WhatWasClicked.Text = “Edit”
    End Sub
 
    Public Sub [Exit]() Implements IExitable.Exit
        WhatWasClicked.Text = “Exit”
    End Sub
 
    Protected Sub btnApplyChanges_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnApplyChanges.Click
        If TypeOf Master Is ICommandButtonContainer Then
            Dim container As ICommandButtonContainer = Master
            container.AddButton.Enabled = AddableCheckbox.Checked
            container.DeleteButton.Enabled = DeletableCheckbox.Checked
            container.EditButton.Enabled = EditableCheckbox.Checked
            container.ExitButton.Enabled = ExitableCheckbox.Checked
        End If
    End Sub
End Class

Note the library will need to reference System.Web.

All I can see is

App_globalresources
App_localresources
App_data
App_browsers
Theme

Argh, I think your code sample above will work for me, but I’m stuck on step 1.

To do this i create a master base page that implements ITeste named BaseMaster (in VB) and i made the property implemented from the interface MustOverride:

Public MustInherit Class BaseMaster

Inherits MasterPage

Implements ITeste

#Region “ITeste Implementation”

MustOverride Property MenuHiddenz() As Boolean Implements ITeste.MenuHiddenz

#End Region

Public Interface ITeste

Property MenuHiddenz() As Boolean

End Interface

Then in the page that “implements” BaseMaster:

Public Overrides Property MenuHiddenz() As Boolean
Get
Return Not Me.MainMenu.Visible
End Get
Set(ByVal value As Boolean)
Me.MainMenu.Visible = Not value
End Set
End Property

Finally, in the custom base page class i can access the master page:

DirectCast(Me.Master, ITeste).MenuHiddenz = True

or in C#

(ITeste)this.Master.MenuHiddenz = true;

Thank’s a lot Wyatt